Si alors

Fonction utilisée :

Article mis à jour le 05/01/2024

Résumé

Sur Excel, il est possible de tester une condition. Si la condition se révèle VRAI, alors nous pourrons afficher une valeur (ou effectuer un calcul donné) et, dans le cas contraire, afficher une autre valeur (ou un autre calcul) si le résultat est FAUX. C’est ce qu’on appelle la logique SI ALORS. Dans notre exemple, la formule dans la cellule C3 est :

=SI( B3="H" ; "Homme" ; "Femme" )

La formule va permettre de vérifier si la cellule B3 est égale à la valeur « H ». Le cas échéant, le résultat retourné sera « Homme ». Dans le cas contraire, la formule renverra la valeur « Femme ».

Formule Excel – Si alors

=SI( test_logique ; résultat_si_vrai ; résultat_si_faux )

Explications

L’objectif de cette formule est de vérifier que la cellule soit égale à « H ». Quand c’est le cas, elle renvoie « Homme » sinon elle affichera la valeur « Femme ». Expliqué avec la construction Si alors, on dit que si B3 est égale à « H » alors on affiche « Homme ».

Fonction SI

C’est la fonction SI sur Excel qui permettra de tester une ou plusieurs conditions et de renvoyer des valeurs différentes en fonction du résultat retourné. Celui-ci sera toujours sous la forme d’un VRAI ou FAUX.

= B3="H"
--> Résultat : VRAI

= B3="F"
--> Résultat : FAUX

C’est ce que l’on appelle un test logique. Ce test s’appuie sur l’opérateur logique « = ». Il existe d’autres opérateurs logiques.

Dans la construction de la fonction SI, il y a 3 arguments. Le premier argument est le test logique. Le second et le troisième argument sont les valeurs (ou nouveaux calculs) que nous voulons afficher si le résultat est respectivement VRAI ou FAUX.

=SI( test_logique ; résultat_si_vrai ; résultat_si_faux )

=SI( B3="H" ; "Homme" ; "Femme" )

=SI( B3="X" ; SOMME(...) ; "ok" )
--> si le test est vrai, on calcule une somme sinon on affiche "ok"

Il est possible de tester des conditions sur du texte, des dates, des nombres,… Dans la formule ci-dessous on vérifie si la cellule A1 est supérieure à 10. Le cas échéant on veut afficher « ok ». Dans le cas contraire, on affiche une valeur nulle (cellule vide).

= SI( A1>10 ; "ok" ; "" )

Explication de l’exemple

Dans l’exemple présent au début de l’article, nous avons une liste de valeurs (H ou F) qui pourrait être un export des salariés d’une entreprise. Nous ne voulons pas avoir l’abréviation mais le sexe de la personne indiqué clairement. Nous voulons alors écrire une formule pour transformer ces abréviations en « Homme » ou « Femme » :

Si la cellule dans la colonne B est égale à « H », on veut « Homme » ;
Si la cellule dans la colonne B est égale à « F », on veut « Femme ».

Pour vérifier l’abréviation dans la colonne B et renvoyer « Homme » ou « Femme », la formule sera :

= SI( B3="H" ; "Homme" ; "Femme" )

La traduction de cette formule est : Si la cellule B3 est égale à « H » alors on veut « Homme » sinon on veut « Femme ».

Les formules ci-dessous ont également le même résultat avec des logiques différentes.

= SI( B3="F" ; "Femme" ; "Homme" )
--> Si la cellule B3 est égale à "F" alors on veut "Femme" sinon "Homme"

= SI( B3<>"H" ; "Femme" ; "Homme" )
--> Si la cellule B3 est différent de "H" alors on veut "Femme" sinon "Homme"

= SI( B3<>"F" ; "Homme" ; "Femme" )
--> Si la cellule B3 est différente de "F" alors on veut "Homme" sinon "Femme"

Tester plusieurs conditions

Dans certains cas, nous voulons tester sur Excel plusieurs conditions. Pour cela, on se servira des fonctions logiques parmi lesquelles nous trouvons :

la fonction ET
la fonction OU

La fonction ET permettra de tester plusieurs conditions et vérifier que tous les résultats se révèlent vrais. Elle renverra la valeur FAUX si au moins un test se révèle erroné.

= ET( 2=2 ; "H"="H" ; 6=6 )
= ET( VRAI ; VRAI ; VRAI)
--> Résultat : VRAI

= ET( 2=2 ; "H"="H" ; 6="Homme" )
= ET( VRAI ; VRAI ; FAUX )
--> Résultat : FAUX

La fonction OU permettra de tester plusieurs conditions et renverra VRAI si au moins un test se révèle VRAI.

= OU( 2=2 ; "H"="F" ; 6=8 )
= OU( VRAI ; FAUX ; FAUX )
--> Résultat : VRAI

= OU( 2=4 ; "H"="F" ; 6=8 )
= OU( FAUX ; FAUX ; FAUX )
--> Résultat : FAUX

Ces fonctions associées à la fonction SI permettront d’effectuer plusieurs tests logiques et de renvoyer des résultats différents suivant les issues.

= SI( OU( 2=2 ; "H"="F" ; 6=8 ) ; "ok" ; "pas ok" )
--> Résultat : "ok"

= SI( ET( 2=2 ; "H"="H" ; 6="Homme" ) ; "ok" ; "pas ok" )
--> Résultat : "pas ok"

Si imbriqués

La fonction SI permet de saisir des formules Excel en tant que résultat (résultat si VRAI ou résultat si FAUX). Nous pouvons saisir n’importe quelle fonction. Il est alors intéressant d’imbriquer les fonctions SI les unes dans les autres. Cela permettra d’effectuer des tests en cascade.

Imaginons que nous aurions saisi en colonne C l’âge de la personne. Nous voulons identifier les hommes et femmes de plus de 40 ans uniquement. Dans tous les autres cas, nous voulons afficher une valeur nulle (« »).

= SI( C3>40 ; SI( B3="H" ; "Homme +40ans" ; "Femme +40ans" ) ; "" )

Dans cette formule, nous vérifions tout d’abord l’âge de l’individu. Si l’âge est supérieur à 40, nous allons vérifier s’il s’agit d’un homme ou d’une femme. Si l’individu à moins de 40 ans, on renverra une valeur nulle.

Formules en lien

5/5 - (1 vote)

Vous avez apprécié cet article ?

Pour me soutenir, cliquez sur cette publicité. Pas besoin d’acheter, un clic suffit.

Merci. 🤩

Annonces

Yann

Créateur de Cleex, ancien contrôleur de gestion dans l’industrie, j’ai à coeur de vous proposer des ressources de qualité pour vous aider à travailler avec Excel.