Fonction TROUVE

La fonction TROUVE est une fonction Excel permettant de récupérer la position d’un caractère ou d’une chaîne de caractères dans un texte. Elle est essentielle dès lors qu’il s’agit de manipuler des textes et d’en extraire des valeurs.

Article mis à jour le 19/05/2023

Syntaxe

La fonction TROUVE s’écrit de la façon suivante :

= TROUVE( texte_cherché ; texte ; [no_départ] )

Cette fonction possède 3 arguments :

texte_cherché – Le caractère ou la chaîne de caractères à retrouver.
texte – Le texte dans lequel on doit rechercher le premier argument.
no_départ – Argument optionnel (par défaut 1). Première position à partir de laquelle on cherche le texte.

La fonction TROUVE permet de récupérer la position d’un caractère ou d’une chaîne de caractères dans un texte.

Dans lequel où il y aurait plusieurs fois le caractère cherché (ou la chaîne de caractères), la fonction renverra uniquement la position du premier. De plus, cette fonction est sensible à la casse. C’est-à-dire qu’elle sera sensible aux majuscules et minuscules. Si vous voulez une fonction non sensible à la casse, il faut se tourner vers la fonction CHERCHE.

Cette fonction est très intéressante à utiliser avec d’autres fonctions de manipulation de texte comme :

La fonction GAUCHE ;
La fonction DROITE.

= TROUVE( "C" ; "Cleex" )
--> Résultat : 1

= TROUVE( "c" ; "Cleex" )
--> Résultat : #valeur
    la fonction est sensible à la casse

= TROUVE( "eex" ; "Cleex" )
--> Résultat : 3

Quelques utilisations de la fonction TROUVE

Retrouver la position d’un caractère dans un texte

Pour retrouver un caractère dans un texte, il suffit d’indiquer en premier argument le caractère cherché en le mettant entre parenthèses et en second argument le texte dans lequel il faut chercher.

Vous avez aussi la possibilité de sélectionner les cellules qui contiennent ces éléments.

= TROUVE( "C" ; "Cleex" )
--> Résultat : 1

= TROUVE( A1 ; B1 )
où A1 contient "C" et B1 contient "Cleex"
--> Résultat : 1

Si la valeur n’est pas présente, la fonction TROUVE renverra #VALEUR. Il en sera de même sur un caractère en minuscule à la place d’une majuscule ou inversement. On dit que la fonction est sensible à la casse.

= TROUVE( "a" ; "Cleex" )
--> Résultat : #VALEUR

= TROUVE( "c" ; "Cleex" )
--> Résultat : #VALEUR

= TROUVE( " " ; "Blog de Cleex" )
--> Résultat : 5
on cherche le 1er espace

Retrouver la position d’une chaîne de caractères avec la fonction TROUVE

De la même, façon il est possible de rechercher une chaîne de caractères avec la fonction TROUVE. Il suffit de mettre cet élément dans le 1er argument de la fonction.

= TROUVE( "eex" ; "Cleex" )
--> Résultat : 3

Récupérer la position de la 2ème occurrence

En se servant du 3e argument de la fonction (l’argument optionnel), il est possible de retrouver la seconde occurrence d’un caractère ou d’une chaîne de caractères.

Cet argument optionnel permet d’indiquer à partir de quelle position dans le texte il faut chercher la valeur indiquée. En imbriquant une fonction TROUVE dans une autre, il est possible d’obtenir la position de la seconde occurrence.

Renouvelez l’opération pour avoir la 3e, 4e,… Occurrence.

= TROUVE( "e" ; "Cleex" ; TROUVE( "e" ; "Cleex" ) + 1 )
--> Résultat : 4

Vérifier si un caractère est présent dans un texte

Si vous voulez vérifier qu’un caractère soit présent sans pour autant récupérer sa position, vous pouvez combiner la fonction TROUVE avec la fonction ESTNUM. Celle-ci vérifie qu’une valeur est numérique. Si la valeur est présente, la formule indiquera VRAI sinon FAUX.

= ESTNUM( TROUVE( "e" ; "Cleex" ) )
--> Résultat : VRAI

Pour afficher une autre valeur que VRAI ou FAUX, vous pouvez combiner le tout avec une fonction SI.

= SI( ESTNUM( TROUVE( "e" ; "Cleex" ) ) ; "Valeur trouvée" ; "" )
--> Résultat : Valeur trouvée

Séparer les prénoms des noms avec la fonction TROUVE

Si vous avez une liste de personnes avec les prénoms et noms séparés par un espace, la fonction TROUVE vous permet de relever la position de l’espace. Grâce à la fonction GAUCHE, qui permet de récupérer les premiers caractères d’un texte, on peut récupérer le prénom.

De la même façon, la fonction DROITE permet de récupérer les derniers caractères d’un texte. En calculant le nombre des caractères entre l’espace et la fin du texte grâce à la fonction NBCAR qui compte les caractère totaux diminué du nombre de caractère jusqu’au premier espace, on peut extraire le nom de famille.

= GAUCHE( 
   "Juste Leblanc" ;
   TROUVE( " " ; "Juste Leblanc" ) 
  )
--> Récupération du prénom

= DROITE( 
    B10 ; 
    NBCAR( B10 ) - TROUVE( C10 ; B10 ) 
  )
--> Récupération du nom

Compartimenter des adresses avec la fonction TROUVE

De la même façon, si vous avez des adresses, vous pouvez vous servir de la présence des virgules pour extraire le numéro de voie.

= GAUCHE( 
   "8, rue Victor Hugo - Paris" ;
   TROUVE( "," ; "8, rue Victor Hugo - Paris" ) 
  )
--> Résultat : 8

Pour une fonction non sensible à la casse, orientez-vous vers la fonction CHERCHE.

Formules en lien

Fonctions en lien

4.8/5 - (31 votes)

Vous avez apprécié cet article ?

Pour me soutenir, cliquez sur cette publicité. Pas besoin d’acheter, un clic suffit.

Merci. 🤩

Annonces

Yann

Créateur de Cleex, ancien contrôleur de gestion dans l’industrie, j’ai à coeur de vous proposer des ressources de qualité pour vous aider à travailler avec Excel.