Résumé
Pour trouver la valeur maximum en appliquant un critère de texte sensible à la casse (présence des majuscules et minuscules), il faut utiliser la fonction MAX, la fonction SI, la fonction ESTERREUR et la fonction TROUVE. Dans l’exemple ci-dessus, la formule en F5 est :
= MAX( SI( ESTERREUR( TROUVE( "PA" ; B5:B10 ) ) ; "" ; D5:D10 ) )Cette formule permet de trouver la valeur maximale dans la plage de valeurs D5:D10 si la valeur « PA » en majuscules est présente dans la plage de cellules B5:B10.
Selon votre version d’Excel, il faudra valider la formule via ctrl+shift+entrée.
Formule Excel – MAX sensible à la casse
= MAX( SI( ESTERREUR( TROUVE( critère ; plage_texte ) ) ; "" ; valeurs ) )Explications
Dans l’exemple, l’objectif est de trouver la plus grande valeur (plage D5:D10) si l’article (présent en B5:B10) contient la valeur « PA ». Nous voulons que la formule soit sensible à la casse c’est-à-dire qu’elle tienne compte de la présence des minuscules et des majuscules. Pour cela, il va falloir associer la fonction MAX, la fonction SI, la fonction ESTERREUR et la fonction TROUVE.
Fonction TROUVE
La fonction TROUVE permet de récupérer la position d’un caractère ou d’une chaîne de caractères dans un texte. Cette fonction est sensible à la casse. C’est-à-dire qu’elle tiendra compte de la présence des majuscules et minuscules. Sa syntaxe est la suivante :
= TROUVE( texte_cherché ; texte ; [no_départ] )Dans notre cas, nous allons appliquer cette recherche sur une plage de cellules en fonction du texte cherché. Le résultat renvoyé sera une plage de valeurs. Si la fonction TROUVE n’identifie pas le texte cherché, elle renverra une erreur
= TROUVE( "PA" ; B5:B10 )
--> Résultat: { #VALEUR! ; #VALEUR! ; 6 ; 5 ; #VALEUR! ; #VALEUR! }Dans notre exemple, seules les 3e et 4e cellules contiennent « PA ». Les autres renvoient une erreur.
Fonction ESTERREUR
La fonction ESTERREUR permet d’identifier les formules qui génèrent des erreurs. Elle renvoie VRAI dès lors que le résultat d’une formule est une erreur.
= ESTERREUR( 6 ) --> FAUX
= ESTERREUR( #VALEUR! ) --> VRAIEn appliquant cette fonction au résultat précédent, nous obtenons une plage de valeurs composée de VRAI/FAUX :
= ESTERREUR( { #VALEUR! ; #VALEUR! ; 6 ; 5 ; #VALEUR! ; #VALEUR! } )
--> Résultat: { VRAI ; VRAI ; FAUX ; FAUX ; VRAI ; VRAI }Fonction SI
La fonction SI permet de réaliser un test et d’afficher un résultat si le test se révèle VRAI ou un autre résultat si le test se révèle FAUX.
= SI( ESTERREUR( 6 ) ; "" ; "ok" ) --> "ok"
= SI( ESTERREUR( #VALEUR! ) ; "" ; "ok" ) --> ""Dans notre exemple, nous voulons neutraliser les valeurs qui ne contiennent pas « PA » et garder les autres :
= SI( ESTERREUR( TROUVE( "PA" ; B5:B10 ) ) ; "" ; D5:D10 )
--> Résultat: { "" ; "" ; 642 ; 833 ; "" ; "" }Les valeurs des articles ne contenant pas « PA » sont transformées en valeurs nulles (« ») et non pas en 0. La valeur 0 est prise en compte dans la fonction MAX tandis que la valeur nulle sera ignorée.
Fonction MAX
La fonction MAX permet de récupérer la valeur la plus élevée dans une série de données. Cette fonction ignore les cellules vides et les textes mais pas les erreurs.
= MAX( "" ; 12 ; 6 ; "test" ; "" )
--> Résultat: 12Si nous appliquons la fonction MAX au résultat précédemment obtenu, nous avons :
= MAX( { "" ; "" ; 642 ; 833 ; "" ; "" } )
--> Résultat: 833Nous obtenons la valeur maximale des articles qui contiennent « PA » en tenant compte de la présence des majuscules.
Formules en lien
- Compter le nombre de cellules contenant une formule
- SOMME.SI plusieurs critères
- Somme si vide
- Compter le nombre de cellules égales à un texte
- Compter le nombre de cellules contenant une partie du texte (mot, caractère)
- Compter nombre de valeurs texte différentes
- Compter le nombre de cellules non vides
- NB.SI avec plusieurs critères
- Trouver des doublons avec NB.SI
- Somme si différent de
- Somme si contient
- MIN.SI.ENS sensible à la casse
- MIN sensible à la casse
- MAX.SI.ENS sensible à la casse
