Fonction SOMME.SI

La fonction SOMME.SI est une fonction Excel permettant de faire la somme suivant l’application d’un critère / d’une condition sur des dates, des textes ou des nombres. Elle supporte les recherches partielles (ex: cellule commençant par).

Article mis à jour le 09/06/2023

Syntaxe

La fonction SOMME.SI s’écrit de la façon suivante :

= SOMME.SI( plage ; critère ; [somme_plage] )

Cette fonction possède trois arguments.

plage – Plage de cellules sur laquelle il faut appliquer le critère.
critère – Critère à appliquer.
[somme_plage] – Argument optionnel. Plage de cellules à additionner. Si le critère est manquant, c’est la plage saisie dans le 1er argument qui sera additionnée.

La fonction SOMME.SI additionne les valeurs dans une plage de cellules suivant un critère donné. Ce critère peut s’appliquer sur la même plage de cellules ou sur une plage adjacente. Il peut s’agir d’un critère sur du texte, des dates ou des valeurs numériques.

S’il faut appliquer plusieurs critères, la meilleure solution sera alors de se tourner vers la fonction SOMME.SI.ENS.

= SOMME.SI( A1:A10 ; "chaise" ; B1:B10 )
--> Somme des cellules B1:B10 si leurs cellules
    adjacentes (A1:A10) sont égales à "chaise"

Comment utiliser la fonction SOMME.SI ?

La fonction SOMME.SI a 3 arguments. Le premier permet de saisir la plage sur laquelle nous allons appliquer un critère. Le second argument est le critère à appliquer. Il faudra utiliser des opérateurs logiques et potentiellement des caractères génériques. Le dernier argument est la plage à additionner. Cet argument est optionnel. S’il n’est pas saisi, c’est la première plage qui est additionnée.

Les critères

La fonction SOMME.SI permet l’utilisation des opérateurs logiques (<, >, <>, <=, >=) et des caractères génériques (*, ?). Pour cela, il faut appliquer une syntaxe particulière. Le tableau suivant résume les différents critères applicables suivant le format de la valeur (nombre, texte, date).

Format	Critère	Syntaxe
Numérique	Valeur égale à 10	10
	Valeur supérieure à 10	">10"
	Valeur inférieure à 10	"<10"
	Valeur supérieure ou égale à 10	">=10"
	Valeur inférieure ou égale à 10	"<=10"
	Valeur différente de 10	"<>10"
Date	Valeur égale au 01/01/2023	"01/01/2023"
	Valeur supérieure au 01/01/2023	">01/01/2023"
	Valeur inférieure à au 01/01/2023	"<01/01/2023"
	Valeur supérieure ou égale au 01/01/2023	">=01/01/2023"
	Valeur inférieure ou égale au 01/01/2023	"<=01/01/2023"
	Valeur différente du 01/01/2023	"<>01/01/2023"
Texte	Valeur égale à "Cleex"	"Cleex"
	Valeur différente de "Cleex"	"<>Cleex"
	Valeur commençant par "Cl"	"Cl*"
	Valeur se terminant par "ex"	"*ex"
	Valeur contenant "ee"	"ee"
	Valeur au format xxx-xxx	"???-???"
Autres	Valeur nulle (peut être le résultat d’une formule)	""
	Cellule vide (pas de formule ni de valeur nulle)	"="
	Cellule non vide	"<>"
Date ou num.	Valeur égale à A1	A1
	Valeur supérieure à A1	">"&A1
	Valeur inférieure à A1	"<"&A1
	Valeur supérieure ou égale à A1	">="&A1
	Valeur inférieure ou égale à A1	"<="&A1
	Valeur différente de A1	"<>"&A1

Quelques utilisations de la fonction SOMME.SI

Additionner les valeurs suivant leurs valeurs

Dans ce premier exemple, nous allons voir comment additionner une plage de cellules selon un critère appliqué sur elle-même. Le critère sera donc forcément numérique.

= SOMME.SI( A1:A10 ; 10 ) --> Valeurs égales à 10
= SOMME.SI( A1:A10 ; ">10" ) --> Valeurs supérieures à 10
= SOMME.SI( A1:A10 ; "<10" ) --> Valeurs inférieures à 10
= SOMME.SI( A1:A10 ; "<>10" ) --> Valeurs différentes de à 10

Additionner des valeurs suivant les valeurs des cellules adjacentes

Si nous prenons l’exemple en en-tête d’article, nous avons une liste d’articles. Nous allons calculer les quantités suivant des critères en lien avec : des nombres, des dates, du texte.

Critères sur des nombres

Pour calculer la somme d’une plage de cellules suivant l’application d’un critère numérique sur une autre plage, inspirez-vous des exemples suivants :

= SOMME.SI( C3:C14 ; ">150" ; D3:D14 ) --> prix égal à 150
= SOMME.SI( C3:C14 ; ">150" ; D3:D14 ) --> prix sup. à 150
= SOMME.SI( C3:C14 ; "<150" ; D3:D14 ) --> prix inf. à 150
= SOMME.SI( C3:C14 ; "<>150" ; D3:D14 ) --> prix diff. de 150
= SOMME.SI( C3:C14 ; ">=150" ; D3:D14 ) --> prix sup. ou égal à 150
= SOMME.SI( C3:C14 ; "<=150" ; D3:D14 ) --> prix inf. ou égal à 150

Critères sur des dates

Pour calculer la somme d’une plage de cellules suivant l’application d’un critère au format date sur une autre plage, inspirez-vous des exemples suivants :

= SOMME.SI( E3:E14 ; "<>08/01/2023" ; D3:D14 )
--> date différente du 08/01/2023

= SOMME.SI( E3:E14 ; ">08/01/2023" ; D3:D14 )
--> date supérieure au 08/01/2023

Critères sur des textes

Pour calculer la somme d’une plage de cellules suivant l’application d’un critère au format texte sur une autre plage, inspirez-vous des exemples suivants :

= SOMME.SI( B3:B14 ; "chaise" ; D3:D14 )
--> si cellule est égale à "chaise"

= SOMME.SI( B3:B14 ; "<>chaise" ; D3:D14 )
--> si cellule est différente de chaise

Critères sur des textes partiels

La fonction SOMME.SI permet de faire des recherches partielles sur du texte. Ainsi nous pouvons mettre des critères tels que « commençant par », « se terminant par », « contenant », « ne contenant pas ». Voici quelques exemples de l’utilisation de caractères génériques.

= SOMME.SI( B3:B14 ; "*bureau*" ; D3:D14 )
--> cellule contenant "bureau"

= SOMME.SI( B3:B14 ; "<>*bureau*" ; D3:D14 )
--> cellule ne contenant pas "bureau"

= SOMME.SI( B3:B14 ; "bureau*" ; D3:D14 )
--> cellule commençant par "bureau"

= SOMME.SI( B3:B14 ; "<>bureau*" ; D3:D14 )
--> cellule ne commençant pas par "bureau"

Critères contenus dans d’autres cellules

Il est possible de faire appel à une cellule contenant le critère désiré. Pour cela, il faudra se servir du caractère & pour joindre les opérateurs logiques et/ou les caractères génériques avec la cellule.

= SOMME.SI( C3:C14 ; ">" & A1 ; D3:D14 )
= SOMME.SI( B3:B14 ; "<>" & A1 ; D3:D14 )
= SOMME.SI( B3:B14 ; "*" & A1 & "*" ; D3:D14 )

Caractéristique de la fonction SOMME.SI

La fonction SOMME.SI permet d’additionner des valeurs suivant une condition sur les cellules additionnées ou des cellules adjacentes ;
Elle ne permet pas d’appliquer plusieurs critères (voir fonction SOMME.SI.ENS) ;
Il faudra mettre les critères entre guillemets dès qu’il s’agira de texte ou qu’il y aura des opérateurs logiques ;
Il faudra lier l’opérateur logique et ses guillemets et la cellule contenant le critère grâce au caractère & ;
La fonction SOMME.SI supporte les recherches partielles grâce aux caractères génériques (*, ?).

Formules en lien

Fonctions en lien

4.9/5 - (19 votes)

Vous avez apprécié cet article ?

Pour me soutenir, cliquez sur cette publicité. Pas besoin d’acheter, un clic suffit.

Merci. 🤩

Annonces

Yann

Créateur de Cleex, ancien contrôleur de gestion dans l’industrie, j’ai à coeur de vous proposer des ressources de qualité pour vous aider à travailler avec Excel.