Convertir texte en date

Fonctions utilisées :
Excel Convertir texte en date

Résumé

Pour convertir un texte en date, car Excel ne reconnait pas qu’il s’agit d’une date, il faudra reconstituer la date en se servant de la fonction DATE, la fonction GAUCHE, la fonction DROITE, la fonction STXT. Dans notre exemple, la formule en C5 est :

=DATE( DROITE(B5;4); STXT(B5;4;2); GAUCHE(B5;2) )

Cette formule reconstitue la date en extrayant du texte l’année, le mois et le jour et en les plaçant dans la fonction DATE.

Formule Excel – Convertir texte en date

=DATE( DROITE(texte;4); STXT(texte;4;2); GAUCHE(texte;2) )

Explications

Il arrive de temps en temps que vos données comportent des dates mais que celles-ci ne soient pas reconnues comme telles par Excel. Il va les interpréter comme du texte.

Il va falloir reconstituer la date en extrayant tour à tour l’année, le mois et le jour. Pour cela, nous allons nous servir de la fonction GAUCHE, la fonction DROITE et la fonction STXT.

Fonction GAUCHE

La fonction GAUCHE permet d’extraire les premiers caractères d’un texte. Elle s’écrit de la façon suivante :

= GAUCHE( texte ; [no_car] )

Le premier argument est le texte duquel on veut extraire les premiers caractères. Le second argument est le nombre de caractères souhaités. Dans notre exemple, cette fonction nous permettra d’extraire le jour sur les 4 premières lignes.

= GAUCHE( B5 ; 2 )

--> Résultat: "01"

Et l’année pour les cellules B9 et B10 :

= GAUCHE( B9 ; 4 )

--> Résultat: "2024"

Fonction DROITE

La fonction DROITE fonctionne de la même façon que la fonction GAUCHE à ceci près qu’elle permet d’extraire les derniers caractères. Elle s’écrit comme ceci :

= DROITE( texte ; [no_car] )

Sur les 4 premières lignes, elle nous permet d’extraire l’année :

= DROITE( B5 ; 4 )

--> Résultat: "2024"

Et le jour pour les cellules B9 et B10 :

= DROITE( B9 ; 2 )

--> Résultat: "26"

Fonction STXT

La fonction STXT permet d’extraire une partie d’un texte en spécifiant le point de départ et le nombre de caractères voulus . Elle s’écrit de la façon suivante :

= STXT( texte ; no_départ ; no_car )

Le premier argument est le texte dont on veut extraire une partie. Le second argument est le numéro du caractère à partir duquel commencer l’extraction. Le dernier argument spécifie le nombre de caractères à extraire.

Dans notre exemple, sur les deux premières lignes, le mois est situé à partir du 4e caractère et est constitué de deux caractères. Nous obtenons :

= STXT( B5 ; 4 ; 2 )

--> Résultat: "01"

Sur les deux lignes suivantes, le mois est placé à partir du 3e caractère :

= STXT( B7 ; 3 ; 2 )

--> Résultat: "06"

Fonction DATE

La fonction DATE permet de reconstituer une date dans un format qu’Excel reconnaitra. Sa syntaxe est la suivante :

=DATE( année ; mois ; jour )

Dans notre exemple, sur les deux premières lignes, on va remplacer chaque argument par les valeurs calculées avec les fonctions précédemment vues.

= DATE( DROITE(B5;4); STXT(B5;4;2); GAUCHE(B5;2) )

--> Résultat: 01/01/2024

Fonction SUBSTITUE

Il arrive que le format de la date soit très proche d’un format valable. Dans notre exemple, les dates sur les deux dernières lignes ont un point en tant que séparateur. Remplacer les points par des « / » peut suffire à ce qu’Excel reconnaisse le format. Pour cela, nous allons utiliser la fonction SUBSTITUE.

Sa syntaxe est la suivante :

= SUBSTITUE( texte ; ancien_texte ; nouveau_texte ; [no_position] )

Les arguments de cette fonction sont :

  • texte – Texte dans lequel il faut remplacer le caractère ou la chaîne de caractères.
  • ancien_texte – Caractère ou chaîne de caractères à remplacer.
  • nouveau_texte – Valeur de remplacement.
  • [no_position] – Argument optionnel (par défaut 1). Numéro d’occurrence du caractère à remplacer.

En ne spécifiant par le dernier argument, nous indiquons à Excel vouloir remplacer tous les caractères correspondant.

Dans notre exemple, nous voulons remplacer tous les points par des « / » :

= SUBSTITUE( B11 ; "." ; "/" )

--> Résultat: 01/01/2024

Avec ce remplacement, Excel reconnait le format date.

Formules en lien

5/5 - (6 votes)

Vous avez apprécié cet article ?

Pour me soutenir, cliquez sur cette publicité. Pas besoin d’acheter, un clic suffit.

Merci. 🤩

Annonces

Modèles Excel

+

Livret 

7 méthodes pour gagner 2H par semaine sur Excel

C’est gratuit 🤩

Les formations

Formations Excel

Parce que chacun devrait avoir les moyens de faire son travail sur Excel

Découvrez des formations accessibles, rapides et directement applicables.