SOMME.SI.ENS avec plusieurs critères sur la même colonne

Résumé

Pour additionner des cellules en fonction de plusieurs critères dont certains s’appliqueront sur la même colonne (ex: égal à « Salon » ou « Cuisine »), on va utiliser la fonction SOMME avec la fonction SOMME.SI.ENS en utilisant une syntaxe particulière. Dans l’exemple ci-dessus, la formule en F3 est :

= SOMME( 
    SOMME.SI.ENS( D3:D10 ; 
                  B3:B10 ; "Chaise" ; 
                  C3:C10 ; {"Salon";"Cuisine"} ) )

Cette formule permet de faire la somme des cellules dans la plage D3:D10 si les cellules dans la plage B3:B10 sont égales à « Chaise » et que les cellules en C3:C10 sont égales à « Salon » ou « Cuisine ».

Formule Excel – SOMME.SI.ENS avec plusieurs critères sur la même colonne

= SOMME( 
    SOMME.SI.ENS( plage_somme  ; 
                  plage_critère_1 ; critère_1 ; 
                  plage_critère_2 ; { critère_2 ; critère_3 } ) )

Explications

Dans l’exemple, l’objectif est d’additionner les quantités (plage D3:D10) correspondant aux chaises (plage B3:B10) des familles Salon et Cuisine (plage C3:C10). Réaliser ce type de formule semble compliqué car il n’y a pas de fonction permettant d’appliquer une logique ou (ex: contenant « Salon » ou « Cuisine »). La fonction SOMME.SI.ENS permet d’appliquer plusieurs critères mais avec une logique et. Les critères vont se cumuler entre eux (ex: Article « Chaise » et famille « Salon »). Il existe deux solutions pour réaliser une fonction SOMME.SI.ENS avec plusieurs critères sur la même colonne.

Fonction SOMME.SI.ENS + Fonction SOMME.SI.ENS

Une façon simple d’appliquer une logique ou est d’utiliser plusieurs fonctions SOMME.SI.ENS :

= SOMME.SI.ENS( D3:D10 ; B3:B10 ; "Chaise" ; C3:C10 ; "Salon" )
  + SOMME.SI.ENS( D3:D10 ; B3:B10 ; "Chaise" ; C3:C10 ; "Cuisine" )

Dans cette formule on calculera dans un premier temps les chaises de la famille Salon puis les chaises de la famille Cuisine. Les résultats seront cumulés pour obtenir la somme totale.

SOMME.SI.ENS avec syntaxe particulière

L’autre façon d’appliquer la logique ou (ex: « Salon » ou « Cuisine ») est d’utiliser une liste de valeur. C’est la méthode utiliser dans notre exemple :

= SOMME( 
    SOMME.SI.ENS( D3:D10 ; 
                  B3:B10 ; "Chaise" ; 
                  C3:C10 ; {"Salon";"Cuisine"} ) )

Dans un premier temps, avec cette syntaxe et l’utilisation des accolades, la fonction SOMME.SI.ENS va renvoyer un résultat pour chaque famille.

= SOMME.SI.ENS( D3:D10 ; 
                B3:B10 ; "Chaise" ; 
                C3:C10 ; {"Salon";"Cuisine"} ) )
--> Résultat: {433;306}

Si vous avez une version récente d’Excel, vous verrez apparaitre à l’écran les deux valeurs dans des cellules superposées. Nous venons de provoquer la création d’une liste de valeurs. Pour obtenir la somme de ces valeurs, il faut englober la fonction SOMME.SI.ENS dans une fonction SOMME.

= SOMME( 
    SOMME.SI.ENS( D3:D10 ; 
                  B3:B10 ; "Chaise" ; 
                  C3:C10 ; {"Salon";"Cuisine"} ) )
--> Résultat: 739

Formules en lien

• Compter le nombre de cellules contenant une formule
• SOMME.SI plusieurs critères
• Somme si vide
• Compter le nombre de cellules égales à un texte
• Compter le nombre de cellules contenant une partie du texte (mot, caractère)
• Compter nombre de valeurs texte différentes
• Compter le nombre de cellules non vides
• NB.SI avec plusieurs critères
• Trouver des doublons avec NB.SI
• Somme si différent de
• Somme si contient