Résumé
Pour comparer deux listes et identifier les doublons, on peut utiliser la fonction RECHERCHEV. Pour un meilleur rendu, on peut l’accompagner de la fonction SI et de la fonction ESTNA. Dans l’exemple ci-dessus, la formule en F5 est :
=SI( ESTNA( RECHERCHEV(B5;$D$5:$D$11;1;FAUX) ) ; "" ; "doublon" )Cette formule vérifie si la valeur AB256 est présente dans la liste Réf. 2 et si tel est le cas, elle renvoie « doublon ». Dans le cas contraire, elle renvoie une valeur nulle (« »).
Formule Excel – RECHERCHEV doublon
= SI( ESTNA( RECHERCHEV(valeur;plage_recherche;1;FAUX) ) ; "" ; "doublon" )Explications
Dans notre exemple, nous avons deux listes avec des codes d’articles. Nous souhaitons vérifier si les codes présents dans la seconde liste sont présents dans la première. Si tel est le cas, nous voulons renvoyer « doublon ». Pour cela, nous allons utiliser la fonction SI, la fonction ESTNA et la fonction RECHERCHEV.
Fonction RECHERCHEV
La fonction RECHERCHEV permet de rechercher verticalement une valeur et de renvoyer une des valeurs situées dans les cellules à sa droite. Dans notre cas, nous souhaitons juste vérifier la présence de la valeur dans la plage de cellules. Nous renvoyons comme résultat la valeur cherchée. Si la valeur est trouvée, elle sera renvoyée. Dans le cas contraire, ce sera l’erreur #N/A qui sera renvoyée.
= RECHERCHEV( B5 ; $D$5:$D$11 ; 1 ; FAUX )
--> Résultat: #N/A
= RECHERCHEV( B7 ; $D$5:$D$11 ; 1 ; FAUX )
--> Résultat: "GD596"Fonction ESTNA
La fonction ESTNA vérifie si la valeur renvoyée par une formule est #N/A. Si c’est le cas, elle renvoie la valeur VRAI sinon elle renvoie la valeur FAUX.
= ESTNA( RECHERCHEV( B5 ; $D$5:$D$11 ; 1 ; FAUX ) )
--> Résultat: VRAI
= ESTNA( RECHERCHEV( B7 ; $D$5:$D$11 ; 1 ; FAUX ) )
--> Résultat: FAUXFonction SI
La fonction SI effectue un test logique puis retourne un résultat différent suivant que le résultat soit VRAI ou FAUX. La syntaxe de la fonction est :
= SI( test_logique ; résultat_si_vrai ; résultat_si_faux )Dans notre exemple, nous pouvons vérifier si le résultat retourné est VRAI et renvoyer une valeur nulle (« ») si c’est le cas. Dans tous les autres cas, nous voulons renvoyer « doublon ».
= SI( ESTNA( RECHERCHEV( B5 ; $D$5:$D$11 ; 1 ; FAUX ) ) ; "" ; "doublon" )
--> Résultat: ""
= SI( ESTNA( RECHERCHEV( B7 ; $D$5:$D$11 ; 1 ; FAUX ) ) ; "" ; "doublon" )
--> Résultat: "doublon"Avec cette formule nous vérifions sur la fonction RECHERCHEV renvoie ou non une erreur. Si tel est le cas, ça signifie que la valeur est absente de la liste et n’est pas en doublon. Dans ce cas, nous voulons afficher une cellule vide.
Si la fonction RECHERCHEV ne renvoie pas d’erreur, il s’agit d’un doublon. La valeur « doublon » sera renvoyée.
Simplifier la formule
Pour aller plus vite, vous pouvez vous contenter d’une formule intégrant la fonction RECHERCHEV. Si celle-ci renvoie #N/A, votre valeur n’est pas en double. Dans le cas contraire, il s’agit d’un doublon.
= RECHERCHEV( B5 ; $D$5:$D$11 ; 1 ; FAUX )
--> Résultat: #N/A
= RECHERCHEV( B7 ; $D$5:$D$11 ; 1 ; FAUX )
--> Résultat: "GD596"
