Résumé
Pour utiliser la fonction RECHERCHEV dans 2 feuilles, il faut les combiner grâce à la fonction SI.NON.DISP. Dans l’exemple ci-dessus, la formule en C5 est :
=SI.NON.DISP(
RECHERCHEV(B5;'Base 1'!A:B;2;FAUX);
RECHERCHEV(B5;'Base 2'!A:B;2;FAUX)
)Cette formule permet de récupérer le prix de chaque article que celui-ci soit stocké dans l’onglet ‘Base 1’ ou dans l’onglet ‘Base 2’.
La fonction SI.NON.DISP est une fonction disponible dans les dernières versions d’Excel. Vous pouvez arriver au même résultat avec la fonction SIERREUR (voir section dans l’article).
Formule Excel – RECHERCHEV dans 2 feuilles
=SI.NON.DISP(
RECHERCHEV( valeur_cherchée ; matrice_1 ; num_col ; FAUX ) ;
RECHERCHEV( valeur_cherchée ; matrice_2 ; num_col ; FAUX )
)Explications
Pour utiliser la fonction RECHERCHEV dans plusieurs onglets, il faut effectuer plusieurs RECHERCHEV et les combiner. Pour cela, nous voulons vérifier tour à tour si la recherche renvoie l’erreur N/A et, le cas échéant, générer une nouvelle recherche dans l’onglet suivant.
C’est la fonction SI.NON.DISP qui nous permettra de combiner les recherches entre elles.
Fonction SI.NON.DISP
La fonction SI.NON.DISP vérifie si une formule renvoie l’erreur #N/A et, le cas échéant, renvoie une autre valeur ou un nouveau calcul. Sa syntaxe est :
= SI.NON.DISP( formule ; valeur_si_na )Dans notre exemple, nous lui indiquons vouloir faire une recherche dans la base 1 et si la valeur est absente, effectuer une autre recherche dans la base 2.
=SI.NON.DISP(
RECHERCHEV(B5;'Base 1'!A:B;2;FAUX);
RECHERCHEV(B5;'Base 2'!A:B;2;FAUX)
)Cette fonction n’est disponible que dans les versions les pus récentes d’Excel. Selon votre version, il faudra peut être se tourner vers la fonction SIERREUR.
Fonction SIERREUR
La fonction SIERREUR fonctionne comme la fonction SI.NON.DISP sauf qu’elle réagira à tous types d’erreurs. Sa force est sa faiblesse car elle peut masquer des erreurs autres que l’erreur N/A.
Notre formule avec la fonction SIERREUR est :
=SIERREUR(
RECHERCHEV(B5;'Base 1'!A:B;2;FAUX);
RECHERCHEV(B5;'Base 2'!A:B;2;FAUX)
)RECHERCHEV dans plusieurs onglets
Pour faire une RECHERCHEV dans plusieurs onglets, il faut utiliser la fonction SI.NON.DISP et autant de RECHERCHEV qu’il y aura de matrices de recherche.
Il faudra appliquer un raisonnement en cascade. Voici un exemple de formule avec 4 matrices de recherche :
=SI.NON.DISP(
RECHERCHEV(B5;'Base 1'!A:B;2;FAUX);
SI.NON.DISP(
RECHERCHEV(B5;'Base 2'!A:B;2;FAUX);
SI.NON.DISP(
RECHERCHEV(B5;'Base 3'!A:B;2;FAUX);
RECHERCHEV(B5;'Base 4'!A:B;2;FAUX);
)
)
)
