Nombre si date comprise entre

Résumé

Pour compter des cellules en fonction d’une date de début et d’une date de fin, vous pouvez utiliser la fonction NB.SI.ENS. Dans l’exemple ci-dessus, la formule en G5 est :

= NB.SI.ENS( B5:B12 ; ">=" & E5 ; B5:B12 ; "<=" & F5 )

Cette formule permet de compter le nombre de cellules dans la plage B5:B12 qui ont une date comprise entre le 15/03/2024 et le 31/05/2024.

Formule Excel – Nombre si date comprise entre

= NB.SI.ENS( dates ; ">=" & début ; dates ; "<=" & fin )

Explications

Dans l’exemple, l’objectif est de compter uniquement les cellules de la colonne B qui ont une date comprise entre une date de début (cellule E5) et une date de fin (cellule F5). Ici, nous voulons que les bornes soient incluses. Le 15/03/2024 et le 31/05/2024 sont des valeurs autorisées. Pour résoudre ce cas, nous allons nous servir de la fonction NB.SI.ENS.

Fonction NB.SI.ENS

La fonction NB.SI.ENS est une fonction Excel permettant de compter des cellules qui remplissent un ou plusieurs critères. Pour cela nous allons utiliser les opérateurs logiques (>, <, <>, =). La fonction NB.SI.ENS s’écrit de la façon suivante :

= NB.SI.ENS( plage_critère1 ; critères1 ; ... )

Dans notre cas, nous voulons compter les cellules de la colonne B :

= NB.SI.ENS( B5:B12 ;

Si les dates présentes sont supérieures ou égales à la borne inférieure (cellule E5). Pour cela, on va utiliser l’opérateur logique >= et le concatener avec la cellule.

= NB.SI.ENS( B5:B12 ; ">=" & E5 ;

Remarquez la synthase particulière « opérateur logique »&cellule. Elle est importante.

A présent, nous voulons définir la borne supérieure. La plage de valeurs sur laquelle appliquer notre critère est de nouveau la plage des dates. Nous voulons qu’elles soient inférieures ou égales à notre borne supérieure (cellule F5).

= NB.SI.ENS( B5:B12 ; ">=" & E5 ; B5:B12 ; "<=" & F5 )

Dans notre exemple, nous avons appliqué plusieurs conditions sur une même plage de valeurs. Ainsi, nous avons pu définir une formule bornant aux deux extrémités les dates voulues.

Ecrire les bornes dans la formule

Dans notre exemple, les dates de début et de fin ont été saisies dans des cellules tierces. C’est la meilleure pratique. Cependant, vous pouvez vouloir saisir les dates directement dans la formule. Je vous conseille de passer par la fonction DATE afin d’éviter toutes problématiques d’interprétation de votre date par Excel.

La syntaxe de la fonction DATE est la suivante :

= DATE( année ; mois ; jour )

En appliquant cette méthode à notre exemple, nous obtenons :

= NB.SI.ENS( B5:B12 ;
             ">=" & DATE( 2024 ; 03 ; 15 ) ; 
             B5:B12 ; 
             "<=" & DATE( 2024 ; 05 ; 31 ) )

Formules en lien

• Somme si date comprise entre
• Compter le nombre de cellules contenant une date
• Compter le nombre de cellules contenant une formule
• SOMME.SI plusieurs critères
• Somme si vide
• Compter le nombre de cellules égales à un texte
• Compter le nombre de cellules contenant une partie du texte (mot, caractère)
• Compter nombre de valeurs texte différentes
• Compter le nombre de cellules non vides
• NB.SI avec plusieurs critères
• Trouver des doublons avec NB.SI
• Somme si différent de
• Somme si contient