Syntaxe
La fonction MOYENNE s’écrit de la façon suivante :
= MOYENNE( nombre1 ; [nombre2] )Cette fonction possède au minimum un seul argument :
nombre1– Un nombre directement saisi, issu d’une cellule, d’une plage de cellules ou le résultat d’une autre formule.nombre2– Argument optionnel. Un autre nombre.
La fonction MOYENNE effectue la moyenne des valeurs numériques saisies dans les différents arguments de la fonction. On peut saisir jusqu’à 255 arguments. On peut combiner les types de références :
- Nombre indiqué dans la formule ;
- Référence à une cellule ;
- Référence à une plage de cellule ;
- Résultat d’une autre formule.
= MOYENNE( 12 ; A1 ; B2:B4 ; SOMME( C2:C4 ) )
--> Résultat :
( 12 + A1 + B2 + B3 + B4 + résultat_somme ) / 6Lors de la moyenne sur une plage de données, si une des cellules est vide. Elle sera ignorée du calcul. Il en va de même pour les cellules contenant du texte.
A1 = 2 ; A2 = 4 ; A3 = vide
= MOYENNE( A1:A3 )
--> Résultat : 6 / 2 = 3Si l’une des cellules renvoie une erreur, la fonction MOYENNE renverra également une erreur. Il en sera de même si vous demandez à Excel de faire la moyenne sur des cellules vides. Il affichera #DIV/0!.
A1 = 2 ; A2 = 4 ; A3 = #VALEUR
= MOYENNE( A1:A3 )
--> Résultat : #VALEURQuelques utilisations de la fonction MOYENNE
Cas simple
Dans ce premier exemple, nous faisons la moyenne sur une plage de cellules.
= MOYENNE( C3:C14 )
En fonction de vos données, la fonction MOYENNE peut renvoyer un nombre avec beaucoup de chiffres après la virgule. Vous pouvez modifier le format de la cellule pour ne faire apparaître que ceux qui vous intéressent. Vous pouvez également combiner la fonction MOYENNE avec la fonction ARRONDI. Le résultat se trouvera arrondi.
= ARRONDI( MOYENNE( C3:C14 ) )
--> Résultat : 153,17Faire la moyenne sur des nombres non reconnus
Excel est en capacité de reconnaître le format d’une cellule. Il saura s’il s’agit d’un nombre ou d’un texte. Cependant, il arrive que lors d’exports d’un logiciel, Excel interprète mal le format et considère des nombres comme des textes. La moyenne ne pourra pas être calculée. Pour corriger ce problème, une solution possible est d’utiliser la fonction CNUM. Elle indiquera à Excel que vos cellules contiennent des nombres.
= MOYENNE( CNUM( C3:C14 ) )
--> Résultat : 153,17
Cette solution a toutefois un inconvénient, une cellule vide sera considérée comme ayant la valeur 0 et viendra impacter la moyenne globale.
Faire une moyenne si condition (moyenne conditionnelle)
Il est possible de faire une moyenne conditionnelle. Il faudra utiliser la fonction MOYENNE.SI. Elle permettra d’ajouter un critère.
= MOYENNE.SI( B3:B14 ; "chaise" ; C3:C14 )
--> Moyenne des prix si l'article est "chaise"
Avec la fonction MOYENNE.SI.ENS, vous pourrez effectuer la moyenne avec plusieurs critères.
= MOYENNE.SI.ENS(
C3:C14 ; plage moyenne
B3:B14 ; plage critère 1
"chaise" ; critère 1
D3:D14 ; plage critère 2
">=150" critère 2
)
--> moyenne des prix des chaises si quantité supérieure
ou égale à 150
Faire la moyenne des plus grandes valeurs
Pour calculer la moyenne des valeurs les plus grandes, il faut utiliser la fonction MOYENNE associée à la fonction GRANDE.VALEUR. La formule ci-dessous calcule la moyenne sur les 3 prix les plus élevés.
= MOYENNE( GRANDE.VALEUR( C3:C14 ; {1;2;3} ) )Faire la moyenne des plus petites valeurs
De la même façon, il est possible de faire la moyenne des plus petites valeurs grâce à la fonction PETITE.VALEUR. La formule ci-dessous calcule la moyenne sur les 4 prix les plus bas.
= MOYENNE( PETITE.VALEUR( C3:C14 ; {1;2;3;4} ) )Faire une moyenne pondérée
Pour faire une moyenne pondérée, on n’utilise pas la fonction MOYENNE mais la fonction SOMMEPROD associée à la fonction SOMME.
= SOMMEPROD( C3:C10 ; D3:D10 ) / SOMME( D3:D10 )
Caractéristiques de la fonction MOYENNE
- La fonction MOYENNE calcule la moyenne des valeurs saisies en tant qu’arguments ;
- Elle ignore les cellules vides ou contenant du texte du calcul ;
- Pour une moyenne conditionnelle, il faut utiliser la fonction MOYENNE.SI ou MOYENNE.SI.ENS ;
- Elle fonctionne avec des dates.
Formules en lien
- Calculer la moyenne pondérée
- Compter le nombre de cellules égales à un texte
- Compter le nombre de cellules contenant du texte
- Compter le nombre de cellules contenant une partie du texte (mot, caractère)
- Compter nombre de valeurs texte différentes
- Compter le nombre de cellules non vides
Le site Cleex rejoint Morpheus Formation, organisme spécialisé dans la formation Excel moderne.
Concrètement, ce qui change pour vous :
