Somme par mois

Fonctions utilisées :

Article mis à jour le 03/01/2024

Résumé

Pour faire la somme par mois dans Excel, vous pouvez utiliser une formule compilant la fonction SOMME.SI.ENS et la fonction FIN.MOIS de la façon suivante :

=SOMME.SI.ENS( $C$3:$C$14 ; 
               $B$3:$B$14 ; ">="&E3 ; 
               $B$3:$B$14 ; "<="&FIN.MOIS(E3;0))

La plage B3:B14 contient les dates et la plage C3:C14 contient les valeurs. La cellule E3 contient le premier jour du mois sur lequel nous voulu obtenir le montant mensuel.

Formule Excel – Somme par mois

=SOMME.SI.ENS( plage_valeurs ; 
               plage_dates ; ">="&premier_jour_mois ; 
               plage_dates ; "<="&FIN.MOIS(premier_jour_mois;0))

Explications

Cette formule Excel permet de faire la somme par mois à partir d’une liste des dates et de valeurs numériques associées. Dans la colonne B ont été indiquées les dates et dans la colonne C ont été indiquées les valeurs numériques. Pour obtenir les sommes par mois, ont été indiquées en colonne E les premiers jours de chaque mois sur lesquels nous voulons avoir le montant mensuel.

Il existe plusieurs façons d’obtenir ce résultat et la solution qui est exposée ici est de se servir de la fonction SOMME.SI.ENS avec la fonction FIN.MOIS.

Fonction SOMME.SI.ENS

La fonction SOMME.SI.ENS est une fonction Excel permettant de faire la somme sur une plage de cellules en fonction d’un ou plusieurs critères. Sa synthaxe est la suivante :

= SOMME.SI.ENS( plage_cellules ; 
                plage_critère_1 ; critère_1 ; 
                plage_critère_2 ; critère_2 ; 
                ...)

Dans notre cas, nous voulons faire la somme de la plage des valeurs numériques.

= SOMME.SI.ENS( C3:C14 ;

Ensuite, nous allons appliquer un critère sur la plage des dates. Nous voulons absolument que la date soit supérieure ou égale au premier jour du mois. Nous avons indiqué le premier jour du mois en cellule E3. Nous devons nous servir de l’opérateur >= avec la synthaxe suivante :

= SOMME.SI.ENS( C3:C14 ;
                B3:B14 ; ">="&E3 ;

Notre dernier critère s’applique de nouveau sur la plage des dates puisque nous voulons que la date soit inférieure ou égale au dernier jour du mois. Voici la synthaxe :

= SOMME.SI.ENS( C3:C14 ;
                B3:B14 ; ">="&E3 ;
                B3:B14 ; "<="& fin_mois )

Nous allons voir à présent comment calculer la fin du mois à partir d’une date donnée.

Fonction FIN.MOIS

La fonction FIN.MOIS permet de calculer le dernier jour du mois à partir d’une date donnée.

=FIN.MOIS( date_départ ; mois )

Cette fonction possède deux arguments :

date de départ – il s’agit d’une date au format valide. Elle peut être issue d’une formule, d’une cellule ou être directement saisie dans la formule.
mois – il s’agit d’un nombre positif ou négatif. Il représente le nombre de mois avant ou après la date de départ.

La fonction FIN.MOIS renvoie la date du dernier jour du mois pour un mois situé dans le passé ou dans le futur par rapport à une date déterminée.

Calcul de la date du dernier jour du mois en cours
= FIN.MOIS( AUJOURDHUI() ; 0 )

Calcul de la date du dernier jour du mois précédent le mois en cours
= FIN.MOIS( AUJOURDHUI() ; -1 )

Calcul de la date du dernier jour du mois suivant le mois en cours
= FIN.MOIS( AUJOURDHUI() ; 1 )

Dans notre exemple, nous avons le premier jour du mois en cellule E3. A partir de cette valeur, nous voulons obtenir la date du dernier jour de ce même mois.

= FIN.MOIS( E3 ; 0 )

En associant la fonction FIN.MOIS à la fonction SOMME.SI.ENS, nous obtenons la formule suivante :

= SOMME.SI.ENS( C3:C14 ;
                B3:B14 ; ">="&E3 ;
                B3:B14 ; "<="&FIN.MOIS(E3;0) )

Il faudra alors à veiller de figer les plages de cellules pour pouvoir étirer la formule dans notre tableau de résultats.

= SOMME.SI.ENS( $C$3:$C$14 ;
                $B$3:$B$14 ; ">="&E3 ;
                $B$3:$B$14 ; "<="&FIN.MOIS(E3;0) )

Formules en lien

4.9/5 - (8 votes)

Vous avez apprécié cet article ?

Pour me soutenir, cliquez sur cette publicité. Pas besoin d’acheter, un clic suffit.

Merci. 🤩

Annonces

Yann

Créateur de Cleex, ancien contrôleur de gestion dans l’industrie, j’ai à coeur de vous proposer des ressources de qualité pour vous aider à travailler avec Excel.