Calcul ancienneté Excel

Résumé

Pour calculer l’ancienneté sur Excel, il faut utiliser la fonction DATEDIF et la fonction AUJOURDHUI. Dans l’exemple présenté, la formule en D5 est :

= DATEDIF( B5 ; AUJOURDHUI() ; "Y" )

Cette formule calculera la date d’ancienneté de la personne en fonction de la date d’entrée et de la date du jour. Pour prendre en compte une date de sortie et/ou une date différente d’aujourd’hui comme dates de références, rendez-vous à la section correspondante.

Formule Excel – Calcul ancienneté

= DATEDIF( date_entree ; AUJOURDHUI() ; "Y" )

Explications

La fonction DATEDIF est spéciale parce que vous ne la retrouverez pas dans les fonctions proposées par Excel. Cependant, elle fonctionne parfaitement avec toutes les versions d’Excel. Elle permet de calculer des écarts entre deux dates exprimés en années, mois et jours.

Dans notre exemple, l’objectif est de calculer l’ancienneté en années. La formule en D5 est :

= DATEDIF( B5 ; AUJOURDHUI() ; "Y" )

Le premier argument est la date inférieure (date de départ). Le second argument est la date supérieure (date de fin). Dans notre exemple, cette dernière a été remplacée par la fonction AUJOURDHUI. Elle retourne la date du jour dans Excel.

Le dernier argument est une lettre exprimant le type de calcul. Il en existe plusieurs. Pour récupérer le nombre d’années totales entre les deux dates, il faut indiquer « Y » (pour « Year »).

= DATEDIF( B5 ; AUJOURDHUI() ; "Y" )

--> Résultat: 20 (à la date du 12/04/2024)

Calcul de la date d’ancienneté à une date spécifique

Pour calculer l’ancienneté par rapport à une date de référence, il suffit de remplacer la fonction AUJOURDHUI par la date en question. Dans notre exemple, nous avons mis la date de référence en cellule D2. Nous obtenons la formule suivante :

= DATEDIF( B5 ; D2 ; "Y" )

--> Résultat: 21

Calcul de la date d’ancienneté en intégrant une date de sortie

Pour prendre en compte une éventuelle date de sortie comme présent dans notre exemple, il est possible d’indiquer à Excel de prendre la bonne date entre la date de référence et la date de sortie. Par principe, la date à sélectionner sera la date la plus ancienne. Pour ça, nous allons utiliser la fonction MIN. Si la date de sortie est absente, ce sera la date de référence qui sera sélectionnée. La formule sera :

= DATEDIF( B5 ; MIN( D2 ; C5 ) ; "Y" )

--> Résultat: 21

Calculer la date d’ancienneté en années et mois

Il est possible de calculer la date d’ancienneté en années et mois. Pour cela, nous allons utiliser la fonction DATEDIF avec l’argument « YM ». Elle nous renverra le nombre de mois totaux depuis le « dernier anniversaire ».

= DATEDIF( B9 ; D2 ; "YM" )

= DATEDIF( "19/05/2018" ; "31/12/2024" ; "YM")

--> Résultat: 7

Le résultat nous indique qu’il s’est écoulé 7 mois complets depuis la dernière date d’anniversaire. La formule suivante permet de concatener les différents résultats et ajouter du texte :

= DATEDIF( B9 ; D2 ; "Y" ) 

  & " années, "

  & DATEDIF( B9 ; D2 ; "YM" )

  & " mois"

--> Résultat: "6 années, 7 mois"

Fonction FRACTION.ANNEE + Fonction ENT

La fonction FRACTION.ANNEE associé à la fonction ENT permettent de calculer l’ancienneté en années.

= ENT( FRACTION.ANNEE( B9 ; D2 ) )

La fonction FRACTION.ANNEE renvoie le nombre d’années s’étant écoulées entre deux dates ainsi que la quote-part de l’année en cours.

= FRACTION.ANNEE( B9 ; D2 )

--> Résultat: 6,62

La fonction ENT permet de garder uniquement la valeur entière du nombre.

= ENT( FRACTION.ANNEE( B9 ; D2 ) )

--> Résultat: 6

Formules en lien

• Calculer l’âge avec la date de naissance
• Différence entre deux dates sans DATEDIF
• Calculer le nombre de jours ouvrés entre deux dates
• Nombre de mois entre deux dates
• Convertir des minutes en heures
• Calculer le trimestre à partir de la date
• Nombre de trimestres entre deux dates
• Nombre d’années entre deux dates
• Ajouter 1 jour à une date
• Convertir des heures en centièmes